Silverstone SST ML08B Carry Handle

24 SEPTEMBER 2025

3D model

I built a new PC after the COVID pandemic when I started working from home some days. I needed a machine which I could transport to and from the office and really didn't want a laptop.

I picked the Silverstone SST ML08B as the case, it was small and came with a carry handle. It was really designed for being used multiple times a week because it was pretty uncomfortable and broke after a few months use.

The Design

I tried a number of different designs, but I'd decided early that I wanted the actual handle part to be a carbon fibre tube. Is it overkill? Yes. Does it look awesome? Also yes.

I also wanted to re-use the existing screw holes and it needed to be strong. Dropping the machine could be catastrophic. I settled on a two-part design. A loop, which connects to the carbon fibre tube, and a cleat which bolts to the machine.

This might seem overly complicated, but there is a method to the madness. Making it in one piece would require putting holes all the way through the part to be able to access the screws. This would weaken the part too much because all the weight would be aligned with the print layers, it needed to be perpendicular.

The cleat approach solves the strength problem, each part can be printed such that the forces are perpendicular to the layers. Admittedly, it is a little annoying to get the case apart now, but that doesn't happen very often and it's a small price to pay for the extra strength.

$fn=80;

module pcTop() {
    cube([370,86,2]);
    
    translate([7,13.5,2]) cylinder(d=3.5,h=4);
    translate([7,13.5+60,2]) cylinder(d=3.5,h=4);
    
    translate([370-31,13.5,2]) cylinder(d=3.5,h=4);
    translate([370-31,13.5+60,2]) cylinder(d=3.5,h=4);
        
}

module tube() {
    translate([0,86/2,22+(25/2)]) rotate([0,90,0]) cylinder(d=25.1,h=345);
}

module handle() {
    module body() {
        hull() {
            cube([14,86,0.01]);
            translate([0,86/2,20]) rotate([0,90,0]) scale([1,0.8,1]) cylinder(d=55,h=14);
        }
    }
    
    module bodyFrame() {  
        cube([14,86,3]);
        
        translate([0,0,3]) difference() {
            body();
            translate([-0.01,10,5.5]) scale([1.01,0.76,0.76]) body();
        }
    }
    
    difference() {
        union() {
            bodyFrame();
            translate([0,86/2,22+(25/2)]) rotate([0,90,0]) cylinder(d=25+6,h=14);
        }
        
        translate([-0.001,0,0]) tube();
        
        translate([-10,-10,-10]) cube([80,80,10]); // flatten the bottom
        
        hull() translate([7,13.5,0]) cleat();
        hull() translate([7,13.5+60,0]) cleat();
    }
}

module cleat() {
    module cleatBody() {
        hull() {
            cube([14,6,0.001], center=true);
            translate([0,0,4]) cube([14,14,0.001], center=true);
        }
    }
    
    difference() {
        cleatBody();
        translate([0,0,-1.45]) screwClearance();
    }
}


module screwClearance() {
    cylinder(d=3.5+0.1,h=3.7);
    translate([0,0,3.7]) cylinder(d=7+0.1,h=1.6+0.2);
}

handle();
//cleat();

%tube();
%translate([0,0,-2]) pcTop();
%translate([332,0,0]) handle();

//part: handle();
//part: cleat();

M0UNTAIN 0F C0DE

Silverstone SST ML08B Carry Handle

The Design